Rename server 2 to bigding

2022-07-26 16:06:32 +01:00
parent 912908f1af
commit 9954c0f177
16 changed files with 158 additions and 109 deletions
--- a/hosts/bigding/rclone.nix
+++ b/hosts/bigding/rclone.nix
@@ -0,0 +1,53 @@
+{
+  pkgs,
+  config,
+  ...
+}: let
+  mountdir = "/var/media/dungflix";
+
+  rclone_config = pkgs.writeText "" ''
+    [dungflix]
+    type = b2
+
+    [dungflix-vault]
+    type = crypt
+    remote = dungflix:dungflix-bucket
+  '';
+in {
+  age.secrets = {
+    dungflix_bucket_account_id.file = ../../secrets/dungflix_bucket_account_id.age;
+    dungflix_bucket_account_key.file = ../../secrets/dungflix_bucket_account_key.age;
+    dungflix_crypt_remote_obscured_pass.file = ../../secrets/dungflix_crypt_remote_obscured_pass.age;
+  };
+  systemd.services.dungflix-mount = {
+    description = "Mount the Backblaze B2 media store";
+    wantedBy = ["multi-user.target"];
+    path = [pkgs.fuse];
+    preStart = ''
+      mkdir -p -m 777 ${mountdir}
+    '';
+    script = ''
+      export RCLONE_B2_ACCOUNT=''$(cat ${config.age.secrets.dungflix_bucket_account_id.path})
+      export RCLONE_B2_KEY=''$(cat ${config.age.secrets.dungflix_bucket_account_key.path})
+      export RCLONE_CRYPT_PASSWORD=''$(cat ${config.age.secrets.dungflix_crypt_remote_obscured_pass.path})
+      ${pkgs.rclone}/bin/rclone --config="${rclone_config}" mount dungflix-vault: ${mountdir} \
+        --transfers 32 \
+        --vfs-cache-mode full \
+        --vfs-cache-max-age 168h \
+        --vfs-cache-max-size 200G \
+        --allow-other \
+        --no-modtime \
+        --buffer-size 4G \
+        --rc \
+        --rc-no-auth \
+        -vv
+    '';
+    postStart = ''
+      sleep 5
+      ${pkgs.rclone}/bin/rclone --config="${rclone_config}" rc vfs/refresh recursive=true _async=true
+    '';
+    serviceConfig = {
+      Restart = "on-failure";
+    };
+  };
+}